/////////////////////////////////////////////////////////////////////
// "On the torsion of rational elliptic curves over sextic fields" //
//        Harris B. Daniels and Enrique González-Jiménez           //
/////////////////////////////////////////////////////////////////////

// 2/8/2018 - Magma 2.23

// Magma script related to Proposition 8 (k) 


//f1 is the j-map from X_0(5) to P1 taken from Zywina, On the possible images of the 
//mod l representations associated to elliptic curves over Q.
//f2 is the j-map from X_{20} to P1 taken from Rouse, Zureick-Brown, Elliptic curves 
//over $\Q$ and $2$-adic images of Galois.

F<t> := FunctionField(Rationals());
f1 := (t^2+10*t+5)^3*t^-1;
f2 := (-4*t^8 + 32*t^7 + 80*t^6 - 288*t^5 - 504*t^4 + 864*t^3 + 1296*t^2 - 864*t - 1188)/(t^4 + 4*t^3 + 6*t^2 + 4*t + 1);
R<x,y>:=PolynomialRing(Rationals(),2);
g:=Numerator(Evaluate(f1,x)-Evaluate(f2,y));
assert IsIrreducible(g);
C<X,Y,Z>:=ProjectiveClosure(Curve(AffineSpace(R),g));
assert Genus(C) eq 3;
_,H,map := IsHyperelliptic(C);

G1, m1 := AutomorphismGroup(H);
phi := m1(G1.2);
G := AutomorphismGroup(H,[phi]);
QC, pi := CurveQuotient(G);
pts := Points(QC : Bound :=100);
E, m2 := EllipticCurve(QC,pts[1]);
assert Rank(E) eq 0;
PTS :=Points(E: Bound:=100);
assert #PTS eq #TorsionSubgroup(E);


PHI := map *pi*m2;
for p in PTS do
assert RationalPoints(p @@ PHI) eq {@ C![0,-1,1], C![0,1,0], C![1,0,0] @};
end for;

/*
Thus there are 2 singular points on C ( [0,-1,1] and [0,1,0] )and one cusp at infinity ( [1,0,0] )
*/